Инструкции, Софт, рекомендации

Здесь обмениваемся советами относительно разного применяемого в нашем деле софта по записям трансляций, обработке видеофайлов.
Рекомендуем программы, делимся опытом использования, разъясняем инструкции, как по софту, так и по другим техническим вопросам по теме форума.

1. Для записи требуется установка Streamlink, curl, jq
2. Поместить код в текстовый файл и переименовать его в "любое название.cmd"

@echo off

echo Livacha
set /p "line=Enter URL or nickname: "

for %%a in ("%line:/=" "%") do set "name=%%~a"

set "user_agent=Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/137.0.0.0 Safari/537.36"
set "url_api=https://livacha.com/api/stream/player?from=web&streamerId=%name%"
set quality=best
set dir=D:\Records
set waiting=30

:loop
cls
title Request...

curl -ksS --url "%url_api%" -H "User-Agent: %user_agent%" -o %name%.json

if %errorlevel% neq 0 (
    echo no response
    del %name%.json 2>nul
    timeout %waiting%
    goto loop
)

echo Livacha - %name%

findstr /c:"code: 400" %name%.json > nul

if %errorlevel% equ 0 (
    title nickname invalid
    echo nickname invalid
    del %name%.json 2>nul
    timeout %waiting%
    goto loop
)

for /f %%a in ('jq ".result.live" -r ^< %name%.json') do set "live=%%a"
for /f %%a in ('jq ".result.servers[0].host" -r ^< %name%.json') do set "host=%%a"

del %name%.json 2>nul

::echo live: %live%
::echo host: %host%

if "%live%"=="false" (
    title %name% is offline
    echo OFFLINE
    timeout %waiting%
    goto loop
)

title %name% - rec
echo online
echo.

set url_stream=https://%host%/hls/%name%.m3u8

set datetime=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%-%time:~3,2%-%time:~6,2%
set datetime=%datetime: =0%
set file=%name%_Livacha_%datetime%.ts

streamlink --stream-segment-threads 3 %url_stream% %quality% -o "%dir%\%file%"

timeout %waiting%
goto loop

В текстовом редакторе изменить путь к своей папке записи:
$dir = "D:\Records"

Запустить скрипт двойным кликом, ввести никнейм, нажать Enter.

+ БАТНИКИ

+ Исправление тайминга (времени) flv записей и быстрая переброска из форматов flv, ts в mp4 и т.д... без потери качества с помощью ffmpeg

+ Как избавиться от лишних элементов при просмотре или записи с экрана на сайте BongaCams (логотип, значки DMCA и прочее)

Значки в кадре трансляции бывают накладными и вшитыми. Вшитые в поток значки можно попытаться удалить редактированием записанного видео.
При записи прямого потока накладных значков, разумеется, не будет.

СПОСОБ №1

Самый простой способ удалить накладные значки при просмотре - воспользоваться внешним окном ("картинка в картинке") в браузерах, где таковая функция имеется (напр. Mozilla).

СПОСОБ №2
Воспользоваться расширением для браузера.

1. Установить расширение для браузера - uBlock Origin или AdBlock Plus или Adblocker Genesis Plus и т.п.
2. В настройках расширения в Мой список фильтров добавить эти фильтры (особенно актуально в гостевом режиме):

+ Фильтры

bongacams25.com###dmca_security
bongacams25.com###layover-logo
bongacams25.com##.chatbox_green
bongacams25.com##.stream_social_links
bongacams25.com##.push_notification_alert
bongacams25.com##.bc_popalert
bongacams25.com##.banner_wrp
bongacams25.com##.__show.nim_ru
bongacams25.com##.modelGamesOutput
bongacams25.com##.__promo.__dice.msg_chat_game.msg_wrp.system_msg
bongacams25.com##.__promo.__wheel.msg_chat_game.msg_wrp.system_msg
bongacams25.com##.__promo.__keno.js-token-keno-promo-container.msg_chat_game.msg_wrp.system_msg
bongacams25.com##.__promo.__slot.msg_chat_game.msg_wrp.system_msg

bongacams25.com##.fancy_popup:style(display: none !important)
bongacams25.com##body:style(overflow: visible !important)

+ Пояснения по фильтрам

#dmca_security - отвечает за скрытие в кадре трансляции накладных значков DMCA (различных видов, главное, чтобы значок был именно накладным, не встроенным в видеопоток).
#layover-logo - убирает в кадре трансляции логотип BongaCams.
.chatbox_green - блокирует появление зеленого окошка справа внизу типа: "Есть время пообщаться?", "Привет, ты откуда?", "Малыш, как тебя зовут?" и прочая хрень.
.stream_social_links - блокировка в окне видео панели значков социальных сетей, напр. Инстаграм.
.push_notification_alert - блокировка появления всплывающего сообщения о предложении подписаться на различные уведомления о акциях и т.п.
.bc_popalert - блокировка иных всплывающих уведомлений.
.banner_wrp - блокировка рекламного баннера вверху справа на главной странице.
.__show.nim_ru - блокировка появления всплывающего сообщения внизу справа на главной странице при залогинивании.
.modelGamesOutput - блокировка в нижней части чата игровой панели.
.__promo.__dice.msg_chat_game.msg_wrp.system_msg - блокировка в чате появления приглашения сыграть в игру "Кости" (Dice).
.__promo.__wheel.msg_chat_game.msg_wrp.system_msg - блокировка в чате появления приглашения сыграть в игру "Колесо" (Wheel).
.__promo.__keno.js-token-keno-promo-container.msg_chat_game.msg_wrp.system_msg - блокировка в чате появления приглашения сыграть в игру "Кено" (Бинго - числовая лотерея) (Keno).
.__promo.__slot.msg_chat_game.msg_wrp.system_msg - блокировка в чате появления приглашения сыграть в игру "Слот-машина" (Slot).

.fancy_popup:style(display: none !important) - блокировка появления всяких всплывающих окон с призывами: зарегистрироваться; купить токены со скидкой; стать PLATINUM, UNLIMITED, SAPPHIRE, TITAN, DIAMOND и EXCLUSIVE; получить VIP статус; попробовать режим невидимки и т.п.
body:style(overflow: visible !important) - фильтр для противодействия скрытия ползунка справа для прокрутки страницы.
**********
## (или ##div) первые две решетки - символ сокрытия элемента.
# (третья решетка по счету) - символ принадлежности элемента по идентификатору (id), например: #dmca_security
. - символ принадлежности элемента по классу (class), например: .chatbox_green

При необходимости отключить какой-нибудь фильтр, его можно не удалять из списка. Достаточно поставить в начале строки с фильтром символ восклицательного знака. Адблокер игнорирует все строки, в начале которых стоит восклицательный знак.
Допустим, вам захотелось вернуть игровую панель в нижнюю часть чата. Выглядеть это будет так:

!bongacams25.com##.modelGamesOutput

Примечание.
1. Вместо числа 25 подставить нужное число (то, которое у вас в адресной строке браузера при нахождении на сайте BongaCams).
2. При использовании фильтров наблюдается блокировка просмотра фоток в профилях моделей.
Пара вариантов для быстрого исправления ситуации:
а) заменить в адресной строке браузера, например: bongacams25.com -> bongacams.xxx и нажать Enter.
б) временно отключить само расширение на сайте - при нажатии на символ расширения в панели инструментов браузера, у адблокеров имеется специальная экспресс кнопка On/Off (затем обновить страницу).

СПОСОБ №3

Способ №3 нужно применять ВМЕСТО способа №2.
Автор - Evgeny.Voloshin
UserScript для BongaCams
Помимо блокирования различных элементов и всплывающих сообщений, скрипт имеет дополнительные преимущества:
а) убирает ограничение времени просмотра для гостей
б) позволяет включить полный экран (fullscreen) в гостевом режиме

Для работы скрипта в браузере должно быть установлено расширение - менеджер пользовательских скриптов (Tampermonkey или Violentmonkey).

+ BongaCams Cleaner.js

// ==UserScript==
// @name         BongaCams Cleaner
// @description  remove pop-ups & view time limit, enable fullscreen
// @version      1.0_RE
// @include      /^https?:\/\/(\D*\.)?bongacams\d*\.com.*/
// ==/UserScript==

const style = document.createElement('style');
style.type = 'text/css';
style.textContent = `
#dmca_security,
#layover-logo,
.chatbox_green,
.stream_social_links,
.push_notification_alert,
.bc_popalert,
.banner_wrp,
.__show.nim_ru,
.modelGamesOutput,
.__promo.__dice.msg_chat_game.msg_wrp.system_msg,
.__promo.__wheel.msg_chat_game.msg_wrp.system_msg,
.__promo.__keno.js-token-keno-promo-container.msg_chat_game.msg_wrp.system_msg,
.__promo.__slot.msg_chat_game.msg_wrp.system_msg,
.fancy_popup {
  display: none !important;
}

body {
    overflow: visible !important;
}

.fullscreen-tooltip {
  display: none !important;
}
`;
document.head.appendChild(style);

const fullscreenBtn = document.getElementsByClassName('button-fullscreen')[0];
let checkExist = setInterval(function() {
  if (fullscreenBtn) {
    const video = document.getElementById('videoView');
    fullscreenBtn.addEventListener('click', function() {
      if (video.requestFullscreen) {
        video.requestFullscreen();
      }
    }, false);
    video.addEventListener('fullscreenchange', function() {
      if (document.fullscreenElement) {
        video.setAttribute('controls','controls');
      } else {
        video.removeAttribute('controls');
      }
    }, false);
    clearInterval(checkExist);
  }
}, 200);

setInterval(function f() {
  for (var i = 0; i < localStorage.length; i++) {
    let key = localStorage.key(i);
    let value = localStorage.getItem(key);
    if(value.match(/^-?\d+$/) && !value.match(/^0$|^1$/) &&
         !key.match(/hover_ts|smiles_supported|player-volume/)) {
      //console.log(key + ' ' + value);
      localStorage.setItem(key, 0);
    }
  }
  return f;
}(), 900000);

В текстовом редакторе (напр. Блокнот) сохранить скопированный код в текстовый файл с расширением .js - BongaCams Cleaner.js

+ Как установить скрипт

**********
поддержать проект: https://www.donationalerts.com/r/evgenyvoloshin

+ Включение анимации превью на сайте Chaturbate

+ Дополнительные инструменты

+ ИНСТРУМЕНТЫ для работы с видео

+ Батник для проверки рабочих зеркал bongacams

@echo off
setlocal enabledelayedexpansion
for /L %%i in (1,1,100) do (
set "url=https://rt.bongacams%%i.com/"
curl.exe --silent --insecure --head --fail --url !url! > nul
if !errorlevel! equ 0 (
echo !url! OK
echo !url! >> bongacams_mirrors_list.txt
) else (
echo !url! XXX
)
timeout /nobreak /t 1 >nul
)
pause

---

+ Как пользоваться поиском по форуму

+20

КОММЕНТАРИИ

Редактор
Рег: 15.03.2017
Ком-ев: 911
Рейтинг: 2703

crazyborder 21 апреля 2026 16:49 #99626

В связи с массовыми блокировками зеркал Chaturbate предлагаются 2 варианта батников для Chaturbate.
Вариант 1. Запрос потока - через прокси. Трафик записи - через ваш реальный IP.
Вариант 2. Весь трафик через VPN.

+ Chaturbate_REC_smart-use-proxy.cmd

@echo off

echo Chaturbate
set /p "line=Enter URL or nickname: "

if "%line:~-1%"=="?" set "line=%line:~0,-1%"
if "%line:~-1%"=="/" set "line=%line:~0,-1%"
for %%a in ("%line:/=" "%") do set "name=%%~a"

set "user_agent=Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:147.0) Gecko/20100101 Firefox/147.0"
set "header=X-Requested-With: XMLHttpRequest"
set "data=room_slug=%name%&bandwidth=high"
set "url_target_proxy=https://chaturbate.com"
set "url_api_proxy=https://chaturbate.com/get_edge_hls_url_ajax/"
set "chars=0123456789ABCDEF"

set quality=1080p,best
set dir=D:\Records
set waiting=30

::Throne
set proxy=127.0.0.1:2080

:start
cls
title Request...

curl -x %proxy% -ksS --url %url_target_proxy%/%name%/ -o %name%.html

if %errorlevel% neq 0 (
    echo no response
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"HTTP 404 - Page Not Found" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"u0022homepage" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"This room has been banned" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title %name% is banned
    echo BANNED
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"This room is not available to your region or gender" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    echo.
    echo *** GEOBLOCK for this proxy ***
    del %name%.html 2>nul
    timeout 1 >nul
    curl -x %proxy% -ksS "http://ip-api.com/line?fields=country"
    echo Attention: Proxy IP change required!
    timeout %waiting%
    goto start
)

for %%a in (%name%.html) do if %%~za equ 0 (
    set "geo_status=not defined"
    del %name%.html 2>nul
    goto loop_proxy
)

set "geo_status=free for this proxy"
del %name%.html 2>nul

:loop_proxy
cls
title Request...
streamlink --version
echo ===========================
echo Chaturbate - %name%
echo %geo_status%
echo.

set "room_status="
set "hls_source="

setlocal enabledelayedexpansion

set "token="
for /l %%i in (1,1,32) do (
    set /a "n=!random! %% 16"
    for %%j in (!n!) do set "token=!token!!chars:~%%j,1!"
)

curl -x %proxy% -ksS --url %url_api_proxy% -H "User-Agent: %user_agent%" -H "X-CSRFToken: %token%" -H "Cookie: csrftoken=%token%" -H "%header%" -d "%data%" -o %name%.json

if %errorlevel% neq 0 (
    title problem
    echo no response from API
    del %name%.json 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"Just a moment" %name%.json > nul

if %errorlevel% equ 0 (
    title problem
    echo proxy - problem - captcha
    del %name%.json 2>nul
    timeout %waiting%
    goto start
)

endlocal

for /f %%a in ('jq ".success" -r ^< %name%.json') do set "success=%%a"
for /f %%a in ('jq ".room_status" -r ^< %name%.json') do set "room_status=%%a"
for /f %%a in ('jq ".url" -r ^< %name%.json') do set "hls_source=%%a"

del %name%.json 2>nul

if "%success%"=="false" (
    cls
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    timeout %waiting%
    goto start
)

if "%room_status%"=="offline" (
    title %name% is offline
    echo OFFLINE
    timeout %waiting%
    goto loop_proxy
)

if "%hls_source%"=="" if "%room_status%"=="public" (
    title problem
    echo public
    echo.
    echo model blocks your proxy:
    curl -x %proxy% -ksS "http://ip-api.com/line?fields=country"
    timeout %waiting%
    goto loop_proxy
)

if "%hls_source%"=="" (
    title %name% is %room_status%
    echo %room_status%
    timeout %waiting%
    goto loop_proxy
)

echo Room: %room_status%

set datetime=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%-%time:~3,2%-%time:~6,2%
set datetime=%datetime: =0%
set file=%name%_CB_%datetime%.ts
title %name% - rec

streamlink --stream-segment-threads 3 %hls_source% %quality% -o "%dir%\%file%"

timeout %waiting%
goto loop_proxy

+ Chaturbate_REC_VPN.cmd

@echo off

echo Chaturbate
set /p "line=Enter URL or nickname: "

if "%line:~-1%"=="?" set "line=%line:~0,-1%"
if "%line:~-1%"=="/" set "line=%line:~0,-1%"
for %%a in ("%line:/=" "%") do set "name=%%~a"

set "user_agent=Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:147.0) Gecko/20100101 Firefox/147.0"
set "header=X-Requested-With: XMLHttpRequest"
set "data=room_slug=%name%&bandwidth=high"
set "url_target=https://chaturbate.com"
set "url_api=https://chaturbate.com/get_edge_hls_url_ajax/"
set "chars=0123456789ABCDEF"

set quality=1080p,best
set dir=D:\Records
set waiting=30

:start
cls
title Request...

curl -ksS --url %url_target%/%name%/ -o %name%.html

if %errorlevel% neq 0 (
    echo no response
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"HTTP 404 - Page Not Found" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"u0022homepage" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"This room has been banned" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title %name% is banned
    echo BANNED
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"This room is not available to your region or gender" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    echo.
    echo *** GEOBLOCK for this IP of your VPN ***
    del %name%.html 2>nul
    timeout 1 >nul
    curl -ksS "http://ip-api.com/line?fields=country"
    echo Attention: IP of your VPN change required!
    timeout %waiting%
    goto start
)

for %%a in (%name%.html) do if %%~za equ 0 (
    set "geo_status=not defined"
    del %name%.html 2>nul
    goto loop
)

set "geo_status=free for this IP"
del %name%.html 2>nul

:loop
cls
title Request...
streamlink --version
echo ===========================
echo Chaturbate - %name%
echo %geo_status%
echo.

set "room_status="
set "hls_source="

setlocal enabledelayedexpansion

set "token="
for /l %%i in (1,1,32) do (
    set /a "n=!random! %% 16"
    for %%j in (!n!) do set "token=!token!!chars:~%%j,1!"
)

curl -ksS --url %url_api% -H "User-Agent: %user_agent%" -H "X-CSRFToken: %token%" -H "Cookie: csrftoken=%token%" -H "%header%" -d "%data%" -o %name%.json

if %errorlevel% neq 0 (
    title problem
    echo no response from API
    del %name%.json 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"Just a moment" %name%.json > nul

if %errorlevel% equ 0 (
    title problem
    echo this IP - problem - captcha
    del %name%.json 2>nul
    timeout %waiting%
    goto start
)

endlocal

for /f %%a in ('jq ".success" -r ^< %name%.json') do set "success=%%a"
for /f %%a in ('jq ".room_status" -r ^< %name%.json') do set "room_status=%%a"
for /f %%a in ('jq ".url" -r ^< %name%.json') do set "hls_source=%%a"

del %name%.json 2>nul

if "%success%"=="false" (
    cls
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    timeout %waiting%
    goto start
)

if "%room_status%"=="offline" (
    title %name% is offline
    echo OFFLINE
    timeout %waiting%
    goto loop
)

if "%hls_source%"=="" if "%room_status%"=="public" (
    title problem
    echo public
    echo.
    echo model blocks this IP of your VPN:
    curl -ksS "http://ip-api.com/line?fields=country"
    timeout %waiting%
    goto loop
)

if "%hls_source%"=="" (
    title %name% is %room_status%
    echo %room_status%
    timeout %waiting%
    goto loop
)

echo Room: %room_status%

set datetime=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%-%time:~3,2%-%time:~6,2%
set datetime=%datetime: =0%
set file=%name%_CB_%datetime%.ts
title %name% - rec

streamlink --stream-segment-threads 3 %hls_source% %quality% -o "%dir%\%file%"

timeout %waiting%
goto loop

Стандартный набор: streamlink, curl, jq

+ spoiler

Примечание.
Вариант 1. Здесь применяется прокси на примере Throne:
set proxy=127.0.0.1:2080
(можете прописать свой рабочий прокси)

Вариант 2. Здесь прописывать не требуется. Подразумевается, что у вас включен VPN на весь трафик ПК.

Местный
Рег: 26.11.2016
Ком-ев: 192
Рейтинг: 620

Bym I 17 апреля 2026 03:21 #99610

К актуальной теме различных способов обхода блокировок.
Throne – преемник\форк заброшенного автором NekoRay. О последнем развёрнутая инфа есть в шапке: Дополнительные инструменты -> NekoRay.
Плюс автоматически обновляемые публичные VPN-конфиги под клиенты, использующие Transport Layer Obfuscation, на другой страничке GitHub. Довольно подробные гайды, в т.ч. видео. Удобно.
(Я не знаю, нужно ли прятать посты (или их фрагменты), касающиеся антиблокировок, под хайд. Прошу модератора сделать это за меня, если необходимо.)
+++++++++
Весьма удобная качалка-заливалка для Меги: MegaBasterd. Нашёл её вскоре после того, как начались блокировки\торможения Mega (из-за их ВПН), и с тех пор только ей и пользуюсь. Гораздо круче, чем MegaDownloader, хотя тот тоже работает с грехом пополам (можно найти у Эльчукабры). В этой софтине прокси не нужно вручную прописывать, всё на автомате.
++++++++++
crazyborder, спасибо за оперативность с обновлением CB-скрипта. А я-то думаю: чегой-то у мну несколько суток чатурная папка пустует?.. CMD на этот раз ошибок не показывал, писал "Offline". (Странно это.) Ладно, думаю, – видно, отдыхают барышни; не стал проверять, работает ли вообще скрипт.
++++++++++

iMDM, 05.04.26: Обновление по записи с Livacha <...> Есть еще программа на Go (исходники/бинарник) для записи с zbiornik.tv. Только на Go нашлась рабочая либа для перехвата WebRTC

Спасибо за обновление для Livacha! И ты поподробнее развернул бы тему про запись по WebRTC, тут несколько раз она поднималась, помнится, и никто ничего внятного не накумекал. Zbiornik.tv мне, например, не знаком, но, может, наши спецы прикрутят эту либу для каких-нибудь других случаев. На той же Ливаче опция WebRTC то появляется, то исчезает в меню просмотра (сейчас её нет, уже довольно давно).

Респект коммьюнити, поклон хозяину...

Редактор
Рег: 15.03.2017
Ком-ев: 911
Рейтинг: 2703

crazyborder 15 апреля 2026 18:06 #99603

HIDE!

Местный
Рег: 19.04.2017
Ком-ев: 86
Рейтинг: 484

Сергей Олейников 15 апреля 2026 11:26 #99601

HIDE!

Любитель
Рег: 30.08.2017
Ком-ев: 406
Рейтинг: 1018

Prohozhij 7 апреля 2026 21:04 #99570

Цитата: Rotorxxxz, 06.04.2026 09:58, №99559

StreamlinkGUI 2.10
Chaturbate
...
у всех так? или только у меня

У меня так же, после привата запись не стартует автоматом, только вручную.

Местный
Рег: 15.12.2016
Ком-ев: 1 709
Рейтинг: 3474

poltergeist 7 апреля 2026 18:38 #99569

@Evgeny.Voloshin,
Огромное Спасибо за обнову GUI

Модератор
Рег: 22.10.2014
Ком-ев: 9 897
Рейтинг: 34013

D-Pulse 6 апреля 2026 17:30 #99566

Цитата: sam

у нового ПО (плейлиста) на чатуре есть особенности:

пишется с чб модель в GUI 2.10. она 2 раза ходила в приваты, более чем на 10 мин, и оба раза запись стартовала заново на выходах из привата, измений в работе не заметил пока ни каких.

@BEAT999,
смотрю первый коммент твой в заблоченном аккаунте Rotorxxxz, и кажется подобная проблема у тебя была на старых версиях GUI в 24 году, значит настройки gui надо еще раз проверить

Любитель
Рег: 22.09.2023
Ком-ев: 48
Рейтинг: 301

BEAT999 6 апреля 2026 16:24 #99565

@sam,
благодарю.
особенно за второй пункт.
теперь понятно почему запись не продолжается после привата

Местный
Рег: 22.09.2021
Ком-ев: 213
Рейтинг: 267

sam 6 апреля 2026 14:58 #99564

у нового ПО (плейлиста) на чатуре есть особенности:

+ spoiler

1. нельзя повторно вызывать: */llhls.m3u8?token=*
вернет ошибку:

HTTP/1.1 403 Forbidden
Server: MMCDN LIVE
X-Reason: w3: session_duplicated

w3: session_duplicated

2. сессия завершается если определенное время не обращаться к: *_llhls.m3u8?session=*
вернет ошибку:

HTTP/1.1 403 Forbidden
Server: MMCDN LIVE
X-Reason: w3: session_missed

w3: session_missed

Новичок
Рег: 9.05.2024
Ком-ев: 8
Рейтинг: 22

Rotorxxxz 6 апреля 2026 13:53 #99562

благодарю.
в settings.txt всё уже давно включено.
и никогда не отключалось.
бонга пишется нормально.
у Chaturbate новый вид плейлиста, поэтому интересуюсь у всех ли скрипт ведет себя так-же как у меня.
что-же касается контента то им от моего лица делиться с сообществом BEAT999.
конечно в меру скромных сил и возможностей (когда трезвый. что случаться крайне редко)

Модератор
Рег: 22.10.2014
Ком-ев: 9 897
Рейтинг: 34013

D-Pulse 6 апреля 2026 12:39 #99560

@Rotorxxxz,
в settings.txt включи функции
StartRecAfterAddingToList=1
CheckModelStatusAfterRecStart=1
StartRecordingIfStatusOnline=1
StartRecAfterLoadList=1

мы все с нетерпением ждем твоих чудесных уловов с чб, как и всех остальных кто просит тут "писалки" и помощь в настройках софта

Новичок
Рег: 9.05.2024
Ком-ев: 8
Рейтинг: 22

Rotorxxxz 6 апреля 2026 09:58 #99559

StreamlinkGUI 2.10
Chaturbate
запись идёт.
модель уходит в приват или офлайн.
после возвращения запись не возобновляться в автомате.
в ручную стоп старт. запись пошла до следующего ухода модели.
если пока модель в привате нажать стоп старт, запись пойдет после выхода модели из привата в автомате. но хватает только на один раз. в следующий повторяю по новой.
у всех так? или только у меня

Новичок
Рег: 7.04.2017
Ком-ев: 149
Рейтинг: 323

wallmaker 6 апреля 2026 09:06 #99558

Подскажите люди добрые рабочие зеркала для чатура?

Любитель
Рег: 29.10.2014
Ком-ев: 57
Рейтинг: 57

iMDM 5 апреля 2026 20:52 #99556

Обновление по записи с Livacha: https://pastebin.com/REiiucRK
Требования: uv (python 3.13+) + httpx + loguru, ffmpeg, streamlink
Главные изменения:
- CLI-утилита, т.е. параметры передаются через аргументы. Пример `run.cmd` файла (в куке может находится символ `%` его нужно экранировать `%%`):

@echo off
set "COOKIE=YOUR_COOKIES_HERE"
set "OUTPUT_DIR=D:\Records\Livacha"
set "RECORDER=streamlink"
set "STREAMERS=streamer1 streamer2"

uv run main.py --cookie "%COOKIE%" --output-dir "%OUTPUT_DIR%" --recorder "%RECORDER%" %STREAMERS%
pause

- теперь стримы можно добавлять на горячую, не закрывая консоль:

Commands:
  + <name>  — add streamer
  - <name>  — remove streamer
  list      — show watched streamers
  help      — show this message

P.S.: Есть еще программа на Go (исходники/бинарник) для записи с zbiornik.tv. Только на Go нашлась рабочая либа для перехвата WebRTC, пришлось писать обвязку тоже на го.

VIP-webcam
Рег: 15.04.2019
Ком-ев: 335
Рейтинг: 3358

Evgeny.Voloshin 4 апреля 2026 01:06 #99551

@poltergeist,
StreamlinkGUI 2.10

Редактор
Рег: 15.03.2017
Ком-ев: 911
Рейтинг: 2703

crazyborder 3 апреля 2026 23:30 #99550

Батник для Chaturbate

+ Chaturbate_REC_via_mir.cmd

@echo off

echo Chaturbate
set /p "line=Enter URL or nickname: "

if "%line:~-1%"=="?" set "line=%line:~0,-1%"
if "%line:~-1%"=="/" set "line=%line:~0,-1%"
for %%a in ("%line:/=" "%") do set "name=%%~a"

set "user_agent=Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:147.0) Gecko/20100101 Firefox/147.0"
set "header=X-Requested-With: XMLHttpRequest"
set "data=room_slug=%name%&bandwidth=high"
set "url_target=https://www.redcams.com"
set "url_api=https://www.redcams.com/get_edge_hls_url_ajax/"
set "url_api_proxy=https://chaturbate.com/get_edge_hls_url_ajax/"
set "chars=0123456789ABCDEF"

set quality=1080p,best
set dir=D:\Records
set waiting=30

::Throne - NekoRay - NekoBox
set proxy=127.0.0.1:2080

:start
cls
title Request...

curl -ksS --url %url_target%/%name%/ -o %name%.html

if %errorlevel% neq 0 (
    echo no response
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"HTTP 404 - Page Not Found" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"u0022homepage" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"This room has been banned" %name%.html > nul

if %errorlevel% equ 0 (
    echo Chaturbate - %name%
    title %name% is banned
    echo BANNED
    del %name%.html 2>nul
    timeout %waiting%
    goto start
)

for %%a in (%name%.html) do if %%~za equ 0 (
    set "geo_status=not defined"
    del %name%.html 2>nul
    goto loop_proxy
)

findstr /c:"This room is not available to your region or gender" %name%.html > nul

if %errorlevel% equ 0 (
    set "geo_status=*** GEOBLOCK ***"
    del %name%.html 2>nul
    goto loop_proxy
)

set "geo_status=free"
del %name%.html 2>nul

:loop_free
cls
title Request...
streamlink --version
echo ===========================
echo Chaturbate - %name%
echo %geo_status%
echo.

set "room_status="
set "hls_source="

setlocal enabledelayedexpansion

set "token="
for /l %%i in (1,1,32) do (
    set /a "n=!random! %% 16"
    for %%j in (!n!) do set "token=!token!!chars:~%%j,1!"
)

curl -ksS --url %url_api% -H "User-Agent: %user_agent%" -H "X-CSRFToken: %token%" -H "Cookie: csrftoken=%token%" -H "%header%" -d "%data%" -o %name%.json

if %errorlevel% neq 0 (
    echo no response from API
    del %name%.json 2>nul
    timeout %waiting%
    goto start
)

endlocal

for /f %%a in ('jq ".success" -r ^< %name%.json') do set "success=%%a"
for /f %%a in ('jq ".room_status" -r ^< %name%.json') do set "room_status=%%a"
for /f %%a in ('jq ".url" -r ^< %name%.json') do set "hls_source=%%a"

del %name%.json 2>nul

if "%success%"=="false" (
    cls
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    timeout %waiting%
    goto start
)

if "%room_status%"=="offline" (
    title %name% is offline
    echo OFFLINE
    timeout %waiting%
    goto loop_free
)

if "%hls_source%"=="" (
    title %name% is %room_status%
    echo %room_status%
    timeout %waiting%
    goto loop_free
)

goto work

:loop_proxy
cls
title Request...
streamlink --version
echo ===========================
echo Chaturbate - %name%
echo %geo_status%
echo.

set "room_status="
set "hls_source="

setlocal enabledelayedexpansion

set "token="
for /l %%i in (1,1,32) do (
    set /a "n=!random! %% 16"
    for %%j in (!n!) do set "token=!token!!chars:~%%j,1!"
)

curl -x %proxy% -ksS --url %url_api_proxy% -H "User-Agent: %user_agent%" -H "X-CSRFToken: %token%" -H "Cookie: csrftoken=%token%" -H "%header%" -d "%data%" -o %name%.json

if %errorlevel% neq 0 (
    title problem
    echo no response from API
    del %name%.json 2>nul
    timeout %waiting%
    goto start
)

findstr /c:"Just a moment" %name%.json > nul

if %errorlevel% equ 0 (
    title problem
    echo proxy - problem - captcha
    del %name%.json 2>nul
    timeout %waiting%
    goto start
)

endlocal

for /f %%a in ('jq ".success" -r ^< %name%.json') do set "success=%%a"
for /f %%a in ('jq ".room_status" -r ^< %name%.json') do set "room_status=%%a"
for /f %%a in ('jq ".url" -r ^< %name%.json') do set "hls_source=%%a"

del %name%.json 2>nul

if "%success%"=="false" (
    cls
    echo Chaturbate - %name%
    title nickname invalid
    echo nickname invalid
    timeout %waiting%
    goto start
)

if "%room_status%"=="offline" (
    title %name% is offline
    echo OFFLINE
    timeout %waiting%
    goto loop_proxy
)

if "%hls_source%"=="" if "%room_status%"=="public" (
    title problem
    echo public
    echo.
    echo model blocks your proxy:
    curl -ksS -x %proxy% "http://ip-api.com/line?fields=country"
    timeout %waiting%
    goto loop_proxy
)

if "%hls_source%"=="" (
    title %name% is %room_status%
    echo %room_status%
    timeout %waiting%
    goto loop_proxy
)

:work

echo Room: %room_status%

set datetime=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%-%time:~3,2%-%time:~6,2%
set datetime=%datetime: =0%
set file=%name%_CB_%datetime%.ts
title %name% - rec

streamlink --stream-segment-threads 3 %hls_source% %quality% -o "%dir%\%file%"

timeout %waiting%

if "%geo_status%"=="free" (
    goto loop_free
) else (
    goto loop_proxy
)

Подставить фактическое рабочее зеркало в двух местах:
set "url_target=https://рабочее зеркало"
set "url_api=https://рабочее зеркало/get_edge_hls_url_ajax/"
***
В батнике используются прокси от Throne (NekoRay - NekoBox):
set proxy=127.0.0.1:2080
Ставьте свои любые, лишь бы рабочие)
***
Стандартный набор: streamlink, curl, jq

streamlink 7.6.0
===========================
Chaturbate - evangel111
*** GEOBLOCK ***

Room: public
[cli][info] Found matching plugin hls for URL https://edge13-rtm.live.mmcdn.com/v1/edge/streams/origin.evangel111.01KNA285T3PSKGC3485D4MS5SA/llhls.m3u8?token=eyJhbGciOiJSU0EtT0FFUC0yNTYiLCJlbmMiOiJBM......
[cli][info] Available streams: 360p (worst), 480p, 540p, 720p_alt, 720p, 1080p (best)
[cli][info] Opening stream: 1080p (hls-multi)
[cli][info] Writing output to
D:\Records\evangel111_CB_2026-04-03_22-58-05.ts
[utils.named_pipe][info] Creating pipe streamlinkpipe-6316-1-8895
[utils.named_pipe][info] Creating pipe streamlinkpipe-6316-2-5609
[download] Written 1.15 GiB to D:\Records\evangel111_CB_2026-04-03_22-58-05.ts (22m18s @ 918.21 KiB/s)

Местный
Рег: 15.12.2016
Ком-ев: 1 709
Рейтинг: 3474

poltergeist 3 апреля 2026 21:57 #99548

@Evgeny.Voloshin,
Доброго дня!
Чатурбейт нам всем подсунул свинью по видимому...от нас всех к тебе, Друг, просьба. Если есть возможность сделать так, чтобы Streamlink GUI снова начал работать как положено. Заранее благодарю от себя и всего коллектива.