@echo off

echo Livacha
set /p "line=Enter URL or nickname: "

for %%a in ("%line:/=" "%") do set "name=%%~a"

:: Читаем куки из файла (должен лежать рядом со скриптом)
set /p mycookies=<cookies.txt

set "user_agent=Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/137.0.0.0 Safari/537.36"
set "url_api=https://livacha.com/api/stream/player?from=web&streamerId=%name%"
set quality=best
set dir=W:\Liva
set waiting=30

:loop
cls
title Requesting %name%...

set /a "rand_wait=%random% %% 5 + 1"
timeout /t %rand_wait% > nul

:: Добавлен заголовок с куками для curl
curl -ksS --connect-timeout 15 --max-time 30 --url "%url_api%" -H "User-Agent: %user_agent%" -H "Cookie: %mycookies%" -o %name%.json

if %errorlevel% neq 0 (
    echo [ERROR] Connection reset or timeout. Code: %errorlevel%
    del %name%.json 2>nul
    timeout %waiting%
    goto loop
)

echo Livacha - %name%

findstr /c:"code: 400" %name%.json > nul

if %errorlevel% equ 0 (
    title INVALID: %name%
    echo [%time%] %name% - nickname invalid or room deleted
    del %name%.json 2>nul
    timeout %waiting%
    goto loop
)

for /f %%a in ('jq ".result.live" -r ^< %name%.json') do set "live=%%a"
for /f %%a in ('jq ".result.servers[0].host" -r ^< %name%.json') do set "host=%%a"

del %name%.json 2>nul

::echo live: %live%
::echo host: %host%

if "%live%"=="false" (
    title %name% is offline
    echo OFFLINE
    timeout %waiting%
    goto loop
)

title %name% - rec
echo online
echo.

set url_stream=https://%host%/hls/%name%.m3u8

set datetime=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%-%time:~3,2%-%time:~6,2%
set datetime=%datetime: =0%
set file=%name%_Livacha_%datetime%.ts

:: Добавлен заголовок с куками для streamlink
streamlink --http-header "Cookie=%mycookies%" --stream-segment-threads 3 %url_stream% %quality% -o "%dir%\%file%"

timeout %waiting%
goto loop