@echo off

set /p name=name: 

set dir=D:\Records
set seconds=30

::NekoBox
set proxy=127.0.0.1:2080

:: if entered full url instead of nickname
echo %name% | findstr /R "https://[a-zA-Z][a-zA-Z]\.stripchat\.com/" > nul
if not errorlevel 1 (
    set name=%name:~25%
)

echo %name% | findstr /R "https://stripchat\.com/" > nul
if not errorlevel 1 (
    set name=%name:~22%
)

echo %name%
echo.

set "frame_resolution="

set /p "frame_resolution=Press Enter to select "best" quality or specify (720, 480, 240, 160): "

if "%frame_resolution%"=="" (
    set "quality=best"
)

if "%frame_resolution%" neq "" (
    set "lastChar=%frame_resolution:~-1%"
)

if "%lastChar%"=="p" (
    set "quality=%frame_resolution%"
)

if "%lastChar%" neq "" (
    if "%lastChar%" neq "p" (
        set "quality=%frame_resolution%p"
    )
)

if not "%quality%"=="best" (
    if not "%quality%"=="720p" (
        if not "%quality%"=="480p" (
            if not "%quality%"=="240p" (
                if not "%quality%"=="160p" (
                    cls
                    echo %name%
                    echo.
                    echo Error - entered value is not from range
                    echo Select "best" quality or 720, 480, 240, 160
                    echo.
                    pause
                    exit
                )
            )
        )
    )
)

:loop
cls

streamlink --version
echo %name% --- Stripchat
echo ===========================

for /f "delims=" %%a in ('curl -ksS https://de.stripchat.com/api/front/v2/users/username/%name%/ ^| jq -r .item.id') do set user_id=%%a

if "%user_id%"=="null" (
    title %name% - nickname incorrect or non-existent
    echo Nickname incorrect or non-existent
    echo.
    pause
    exit
)

set "is_CamAvailable="

sleep 0.5
for /f "delims=" %%a in ('curl -ksS https://de.stripchat.com/api/front/v2/models/username/%name%/cam ^| jq -r .user.isGeoBanned') do set is_GeoBanned=%%a

echo GeoBanned: %is_GeoBanned%

sleep 0.5
if "%is_GeoBanned%"=="false" (
    for /f "delims=" %%a in ('curl -ksS https://de.stripchat.com/api/front/v2/models/username/%name%/cam ^| jq -r .cam.isCamAvailable 2^>nul') do set is_CamAvailable=%%a
    goto check_cam
)

if "%is_GeoBanned%"=="true" (
    for /f "delims=" %%a in ('curl -x %proxy% -ksS https://de.stripchat.com/api/front/v2/models/username/%name%/cam 2^>^&1 ^| findstr /c:"Failed to connect to" 2^>nul') do set "is_CamAvailable=error"
)

if "%is_CamAvailable%"=="error" (
    title %name% - proxy error
    echo Proxy is not working or no response from the server
    timeout %seconds%
    goto loop
)

sleep 0.5
for /f "delims=" %%a in ('curl -x %proxy% -ksS https://de.stripchat.com/api/front/v2/models/username/%name%/cam ^| jq -r .cam.isCamAvailable 2^>nul') do set "is_CamAvailable=%%a"

:check_cam

if "%is_CamAvailable%"=="" (
    title Camera is not available
    echo Camera is not available
    echo Nickname is probably not a model
    echo.
    pause
    exit
)

if "%is_CamAvailable%"=="false" (
    title %name% - camera is not available
    echo Camera is not available
    echo Model is offline or in private chat
    timeout %seconds%
    goto loop
)

if "%is_CamAvailable%"=="true" (
    goto continue
)

:continue

echo Online is %is_CamAvailable%

set datetime=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%-%time:~3,2%-%time:~6,2%
set datetime=%datetime: =0%
set file=StripChat_%name%_%datetime%.ts
title Rec - %name%_%datetime%

setlocal enabledelayedexpansion

if "%quality%"=="720p" (
    for /f "tokens=*" %%a in ('streamlink https://edge-hls.doppiocdn.com/hls/%user_id%/master/%user_id%_auto.m3u8') do set out_line=%%a
    echo !out_line! | findstr "720p" >nul
    if not errorlevel 1 (
        goto work
    ) else (
        echo Error - selected value '720p' was not found
        echo.
        pause
        exit
    )
)

:work

if "%quality%"=="best" (
    streamlink --stream-segment-threads 3 https://edge-hls.doppiocdn.com/hls/%user_id%/master/%user_id%.m3u8 %quality% -o "%dir%\%file%"
) else (
    streamlink --stream-segment-threads 3 https://edge-hls.doppiocdn.com/hls/%user_id%/master/%user_id%_auto.m3u8 %quality% -o "%dir%\%file%"
)

timeout %seconds%
goto loop