@echo off
setlocal enabledelayedexpansion

echo Livacha
set /p "line=Enter URL or nickname: "

for %%a in ("%line:/=" "%") do set "name=%%~a"

set "user_agent=Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/137.0.0.0 Safari/537.36"
set "url_api=https://livacha.com/api/stream/player?from=web&streamerId=%name%"
set quality=best
set dir=W:\_Liva
set waiting=30
set retry_delay=10
set max_attempts=3

:loop
cls
title Request...

curl -ksS --url "%url_api%" -H "User-Agent: %user_agent%" -o %name%.json

if %errorlevel% neq 0 (
    echo no response
    del %name%.json 2>nul
    timeout /t %waiting%
    goto loop
)

echo Livacha - %name%

findstr /c:"code: 400" %name%.json > nul
if %errorlevel% equ 0 (
    title nickname invalid
    echo nickname invalid
    del %name%.json 2>nul
    timeout /t %waiting%
    goto loop
)

for /f %%a in ('jq ".result.live" -r ^< %name%.json') do set "live=%%a"
for /f %%a in ('jq ".result.servers[0].host" -r ^< %name%.json') do set "host=%%a"

del %name%.json 2>nul

if "%live%"=="false" (
    title %name% is offline
    echo OFFLINE
    timeout /t %waiting%
    goto loop
)

title %name% - rec
echo ONLINE
echo.

:: Ссылки и имя файла
set "url_hls=https://%host%/hls/%name%.m3u8"
set "url_flv=https://%host%/flv/%name%.flv"
set datetime=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%-%time:~3,2%-%time:~6,2%
set datetime=%datetime: =0%
set "file_ts=%dir%\%name%_Livacha_%datetime%.ts"
set "file_flv=%dir%\%name%_Livacha_%datetime%.flv"

:: Попытки HLS
set /a attempt=1
:retry_hls
echo Attempt !attempt! to record via HLS...
streamlink --stream-segment-threads 3 %url_hls% %quality% -o "%file_ts%"
if !errorlevel! equ 0 (
    echo HLS recording succeeded.
    timeout /t %waiting%
    goto loop
)

if !attempt! lss %max_attempts% (
    echo HLS failed, retrying in %retry_delay% seconds...
    timeout /t %retry_delay%
    set /a attempt+=1
    goto retry_hls
)

:: Переход к FLV после неудачных HLS
echo All HLS attempts failed. Switching to FLV...

ffmpeg -hide_banner -y -i "%url_flv%" -c copy "%file_flv%"

timeout /t %waiting%
goto loop