@echo off
setlocal enabledelayedexpansion

set /p name=name:
set quality=best
set dir=D:\
set seconds=30

set header="X-Requested-With: XMLHttpRequest"
set data="method=getRoomData&args%%5B%%5D=%name%&args%%5B%%5D=false"
set url="https://bongacams.com/tools/amf.php"
set user_agent="Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/79.0.3945.130 Safari/537.36"
set curl_exe=curl.exe --silent --show-error --user-agent %user_agent% --header %header% --data %data% --url %url%

:start
cls

curl --silent --show-error --location --head --user-agent %user_agent% --write-out %%{url_effective} --url https://bongacams.com/%name% --output nul | find "/profile/" > nul

if not errorlevel 1 (
  title %name% - offline
  echo Room status: offline
  timeout %seconds%
  goto start

) else (

  for /f "delims=" %%a in ('%curl_exe% ^| jq -r .performerData.showType') do @set showType=%%a

  if not "!showType!"=="null" (
    if not "!showType!"=="public" (
      cls
      title %name% - !showType!
      echo Room status: !showType!
      timeout %seconds%
      goto start
  
    ) else (

      for /f "delims=" %%a in ('%curl_exe% ^| jq -r .localData.videoServerUrl') do @set videoServerUrl=%%a

      cls
      echo Room status: !showType!
      set date_time=!date:~6,4!-!date:~3,2!-!date:~0,2!_!time:~0,2!-!time:~3,2!-!time:~6,2!
      set date_time=!date_time: =0!
      title %name% - recording
      streamlink --hls-segment-threads 3 https:!videoServerUrl!/hls/stream_%name%/playlist.m3u8 %quality% --output "%dir%BongaCams-%name%-!date_time!.ts"
      timeout %seconds%
      goto start
    )

  ) else (

    cls
    title %name% - error
    echo Something went wrong
    timeout %seconds%
    goto start	

  )
)